@ SCEPTRE 5.50 PATCH UCS_P550_016
@ SCL TO PROVIDE AND EXECUTE CODE TO AMEND PATCH FILES
@ TO ENSURE THAT PATCHES ARE TIMESTAMPED
BEGIN
LIBRARY := "ICLRSISOURCE"
ED1_FILE := LIBRARY + ".UCSP550016EDIT1"
ED2_FILE := LIBRARY + ".UCSP550016EDIT2"
ACT_SOURCE := LIBRARY + ".UCSP550016ACTPROC"
PROC_SOURCE := LIBRARY + ".UCS_ADD_PATCH_DATES"
BEGIN
     INT IGNORE
     XFGEN(VAL ED1_FILE,RES=IGNORE)
     XFGEN(VAL ED2_FILE,RES=IGNORE)
     XFGEN(VAL ACT_SOURCE,RES=IGNORE)
     XFGEN(VAL PROC_SOURCE,RES=IGNORE)
     XF(VAL ED1_FILE,RES=IGNORE)
     XF(VAL ED2_FILE,RES=IGNORE)
     XF(VAL ACT_SOURCE,RES=IGNORE)
     XF(VAL PROC_SOURCE,RES=IGNORE)
     XF(ICLRSIOMF.UCSP550016ACTPROC,RES=IGNORE)
     XF(ICLRSIOMF.UCSADDPATCHDATES,RES=IGNORE)
END
INF(VAL ED1_FILE)
----
PS/ALTER(1900,TO=DATESTAMP)/
ABN
++++
INF(VAL ED2_FILE)
----
TC/@ insert amendments before this line/
/INS +1
POINT(UCS093.PATCHES)
ALTER(1900,TO=DATESTAMP)
/E
++++
INF(VAL ACT_SOURCE)
----
PROC UCSP550016ACTPROC IS (INT FILE)
BEGIN
INT FLAG
STRING FILENAME := FILL(30)
GN(FILE,TYPE=T,BUFF=FILENAME)
BEGIN
     STOPT(LOWRITES)
     ED(*FILE,TEMPFILE,EDIT=ICLRSISOURCE.UCSP550016EDIT1,RES=FLAG)
END
IF FLAG = -41703 @ EDIT ABANDONED AS WE FOUND THE CODE
     THEN
     SMSG(FILENAME + " NO ACTION REQUIRED")
     RETURN
ELSF FLAG = 36032 @ NOT FOUND - NEED TO INSERT
     THEN
     FLAG := 0
     BEGIN
          STOPT(LOWRITES)
          ED(*FILE,EDIT=ICLRSISOURCE.UCSP550016EDIT2,RES=FLAG)
     END
     IF FLAG = 0
          THEN
          SMSG(FILENAME + " AMENDED OK")
          RETURN
     FI
FI
IF FLAG NE 0
     THEN
     SMSG(FILENAME + " RETURNED UNEXPECTED ERROR " + NUMERIC(FLAG))
     QUITSCL
FI
END
++++
INF(VAL PROC_SOURCE)
----
PROC UCS_ADD_PATCH_DATES IS (RESPONSE (RESPONSE) REPLY := RESULT)
BEGIN
DLBD(ICLRSISOURCE,,NONE&HIGHEST,STA=ICL8UCSP,ICL8UCSP,
     ACT=UCSP550016ACTPROC)
END
++++
CSCL(VAL ACT_SOURCE,ICLRSIOMF)
CSCL(VAL PROC_SOURCE,ICLRSIOMF)
UCS_ADD_PATCH_DATES