@ SCEPTRE AMENDMENT UCS_P550_018
@
@ Release 5.5
@ Date 29 SEPTEMBER 1999
@
@ Overlord stops producing Vigilant Alerts following the
@ Sceptre 5.50 upgrade.
@
@ This is due to the fact that the Overlord Post PJE hook
@ was reissued with Sceptre 5.50, which would have removed
@ the call to UCV_ASSIGN_CODE that any site using Overlord
@ and Vigilant will have inserted into the hook at Sceptre
@ release 5.00.
@
@ The following SCL will create a new copy of the hook, which
@ includes the required call to UCV_ASSIGN_CODE.
@
@ It should be executed once under :SCEP0550, and will produce
@ the module :SCEP0550.ICLRSIOMF.ICL8UCSOVLDPOSTPJE.
@
@ In order for the new version to be implemented, you must then copy
@ this module to the INSTLIB belonging to each VME system owner. This
@ is a manual action to be performed by the user.
@
@ The change will be effective from the next time the Overlord VM is
@ started.
@
@-----------------------------------------------------------------------
BEGIN
INT FLAG := 0
INF(ICLRSISOURCE.ICL8UCSOVLDPOSTPJE, RES=FLAG)
----
PROC ICL8_UCS_OVLD_POST_PJE ( UC_OVLD_POST_PJE ) IS ()
PROCBEGIN
@
@   POST-PJE Procedure for the Overlord monitor when running as a
@   system task.
@
BEGIN
@
@  EXTERNAL PROCEDURES
@
EXT PROC ECFH_UPDATE_PRIVILEGED_OCF IS (
         SPDW,SPDW,INT,SPDT,REF STRING,SPDI,RESPONSE );
 
EXT PROC END_VM IS (RESPONSE RESPONSE := RESULT)
 
EXT PROC SELECTUSEROBJECT (NORESCHEDULE) IS (
      LITERAL         NAME,
      REF INT         LNAME,
      REF INT         NOT_USED := NIL,
      RESPONSE        RESPONSE := RESULT )
EXT PROC GIVEUSEROBJECTDETAILS (NORESCHEDULE) IS (
      LITERAL         NAME,
      INT             ITEM := 1,
      REF INT         INTVALUE := NIL,
      REF STRING      STRINGVALUE := NIL,
      REF INT         LENGTHOFSTRING := NIL,
      LITERAL         BASICORUDATA := "BASIC",
      RESPONSE        RESPONSE := RESULT )
  EXT PROC OSCL_GIVE_JOB_DATA IS (STRING,REF STRING,SPDRVIW,RESPONSE)
@
@ Variable definitions
@
INT ICL8UCS0JPP_RESP := 0,
    ICL8UCS0JPP_AKEY := 0;
 
STRING ICL8UCS0JPP_OL
 
STRING OSDL_TABLES := FILL(256),
       LOCAL_ALERTS_FILE := FILL(256),
       ALLOCATION := FILL(256)
STRING POSN = "INITIALISING"
STRING THIS_JOB_TAG
(1) INT LEN
STRING TYPE := HEX(0D)
STRING DET := FILL(100)
INT R_TYPE,
    R_LEN,
    LOC_RES,
      RESX := 0
 
@
@ Error handler
@
  WHENEVER RESX  NE 0  THEN
     SMSG("UCSOVLDPOSTPJE FAILED WHEN " + POSN)
     SMSG("RESULT : " + NUMERIC(RESX))
     RETURN
  FI
@
@ Start of code
@
  POSN := "OBTAINING JOB TAG"
 
  OSCL_GIVE_JOB_DATA(TYPE,DET,LEN,RESX)
  R_TYPE := STINT(SUBSTR(DET,0,1))
  R_LEN  := STINT(SUBSTR(DET,1,1))
  IF R_TYPE EQ 13
  THEN
    THIS_JOB_TAG := SUBSTR(DET,2,R_LEN)
  ELSE
    RESX := 80000
  FI
 
  STRING UON_NAME := "ICL8UCSOV"+THIS_JOB_TAG+"(OVERLORD)"
 
  POSN := "SELECTING OBJECT"
 
  SELECT_USER_OBJECT(NAM = VAL UON_NAME,
                     LNA = UCSOVUON,
                     RES = RESX)
 
  POSN = "OBTAINING UCSOVERLORD PARAMETERS"
 
  GIVE_USER_OBJECT_DETAILS(NAM  = *UCSOVUON,
                          ITEM = 1,
                          STRING_VALUE = OSDL_TABLES,
                          RES = RESX)
 
 
  GIVE_USER_OBJECT_DETAILS(NAM = *UCSOVUON,
                            ITEM = 2,
                            STRING_VALUE = LOCAL_ALERTS_FILE,
                            RES = RESX)
 
  GIVE_USER_OBJECT_DETAILS(NAM  = *UCSOVUON,
                           ITEM = 3,
                           STRING_VALUE = ALLOCATION,
                           RES = RESX)
 
 POSN := "UPDATING OCF"
 ICL8UCS0JPP_OL := THIS_JOB_TAG +" R OVERLORD_TASK    OVERLORD MONITOR";
 ICL8UCS0JPP_AKEY := STINT(THIS_JOB_TAG);
 
 ECFH_UPDATE_PRIVILEGED_OCF( 17 , ICL8UCS0JPP_AKEY ,-1,
                             FALSE , ICL8UCS0JPP_OL ,
                             -1 , ICL8UCS0JPP_RESP );
 
 BEGIN+1
 
@
@ Now at ACR 10
@ ~~~~~~~~~~~~~
 
    INT RESULT,
        OMF ,
        SRC ;
 
    ALB( OMFLIBRARY , OMF , E , RES=RESULT );
    ALB( SOURCELIBRARY , SRC , RES=RESULT );
 
    UCS_ASSIGN_CODE();
    UCV_ASSIGN_CODE();
 
    POSN = "RUNNING OVERLORD"
 
    STRING COMMAND_LINE :=
      "UCSOVERLORD(OVERLORD_TABLES = " + OSDL_TABLES +
              ",LOCAL_ALERT_FILE = " + LOCAL_ALERTS_FILE +
              ",ALLOCATION = " + ALLOCATION +
              ",RES = RESULT)"
    UCS_EXSCL(LIN=COMMAND_LINE)
 
END
 
 ECFH_UPDATE_PRIVILEGED_OCF( 17 , ICL8UCS0JPP_AKEY ,-1,
                             FALSE , NIL ,
                             -1 , ICL8UCS0JPP_RESP );
 
END_VM();
 
END
PROCEND
++++
IF FLAG NE 0
     THEN
     SMSG("INPUT FAILS - RESULT CODE = " + NUMERIC(FLAG))
     RESULT := FLAG
ELSE
     CSCL(ICLRSISOURCE.ICL8UCSOVLDPOSTPJE,ICLRSIOMF,CODE=NW,RES=FLAG)
     IF FLAG NE 0
          THEN
          SMSG("CSCL FAILS - RESULT CODE = " + NUMERIC(FLAG))
          RESULT := FLAG
     ELSE
          SMSG("Module ICLRSIOMF.ICL8UCSOVLDPOSTPJE Created OK")
          SMSG("This now needs to be copied to all VME System Owners")
          SMSG("using the VME AMENDMODULE command.")
     FI
FI
END